home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Megahits 6
/
Megahits 6 (1995)(GTI - Rhein-Main-Soft)(DE)(Disc 2 of 2)[!].iso
/
time_ungepackt
/
time_361_390
/
time_381
/
amigakonto
/
hdinstall
< prev
next >
Wrap
Text File
|
1995-07-15
|
5KB
|
186 lines
; Installationsskript für AmigaKonto_Demo V2.2
; erstellt für Installer V1.24, 22.2.95, Autor: Andreas Regul
; Copyright-Hinweise für Installer:
; Installer and Installer project icon
; (c) Copyright 1991-93 Commodore-Amiga, Inc. All Rights Reserved.
; Reproduced and distributed under license from Commodore.
; INSTALLER SOFTWARE IS PROVIDED "AS-IS" AND SUBJECT TO CHANGE;
; NO WARRANTIES ARE MADE. ALL USE IS AT YOUR OWN RISK. NO LIABILITY
; OR RESPONSIBILITY IS ASSUMED.
(set @default-dest "SYS:")
(set @user-level 2)
(set @error-msg (cat "AmigaKonto wurde nicht komplett installiert. Bitte wiederholen Sie die Installation, "
"um eine lauffähige Version auf Ihrer Festplatte zu erhalten."))
(complete 0)
(welcome "Willkommen zur Festplatten-Installation von AmigaKonto.\n")
(set mydir
(askdir
(prompt "Bitte wählen Sie das Laufwerk für AmigaKonto")
(help "Für AmigaKonto wird ein eigenes Verzeichnis "
"auf der Festplatte benötigt. Um dieses Verzeichnis "
"anlegen zu können, müssen Sie hier die Festplatte "
"angeben, auf der installiert werden soll (z.B. Work:, DH0:, etc).\n"
)
(newpath)
(default @default-dest)
(disk)
)
)
(set @default-dest (tackon mydir "AmigaKonto"))
(set icondir (tackon @default-dest "Icons"))
(set exampledir (tackon @default-dest "Beispiel"))
(if (NOT (exists @default-dest))
(makedir @default-dest
(prompt "Das Verzeichnis \'" @default-dest "\' wird erzeugt. Bitte \'Proceed\' anklicken.")
(confirm)
(help "Auf dem von Ihnen ausgewählten Laufwerk wird das Unterverzeichnis "
"für AmigaKonto angelegt. Sollten Sie doch einen anderen Pfad als "
"\'" @default-dest "\' verwenden wollen, können Sie das Installations- "
"programm an dieser Stelle abbrechen. Beim Neustart geben Sie dann den "
"von Ihnen gewünschten Pfad an.\n\n"
"Als Verzeichnisname wird jedoch in jedem Fall 'AmigaKonto' verwendet.\n")
(infos)
)
)
(complete 5)
; Verzeichnis für Icons erzeugen
(if (NOT (exists icondir))
(makedir icondir
(infos)
)
)
(complete 7)
; Verzeichnis für Beispielkonto erzeugen
(if (NOT (exists exampledir))
(makedir exampledir
(infos)
)
)
(complete 10)
(message "Als nächstes werden die Programmdateien kopiert. Bitte \'Proceed\' anklicken, um fortzufahren.")
; Programmdateien kopieren
(copyfiles
(prompt "Kopiere Programmdateien")
(help "")
(source "")
(dest @default-dest)
(choices "AmigaKonto"
"AmigaKonto.info")
(optional force askuser)
)
(complete 50)
; Icons kopieren
(copyfiles
(prompt "Kopiere Icons")
(help "")
(source "Icons")
(dest icondir)
(optional force askuser)
(all)
)
(complete 60)
(set osversion (/ (getversion) 65536))
; Voreinstellung kopieren
(if (< osversion 36)
(copyfiles
(prompt "Kopiere Voreinstellung")
(help "")
(source "AmigaKonto.prefs")
(dest @default-dest)
)
(copyfiles
(prompt "Kopiere Voreinstellung")
(help "")
(source "AmigaKonto.prefs")
(dest "ENVARC:")
)
)
(complete 70)
; Dokumentation kopieren
(copyfiles
(prompt "Kopiere Dokumentation")
(help "")
(source "")
(dest @default-dest)
(choices "AmigaKonto.dok"
"AmigaKonto.dok.info"
"Bitte lesen"
"Bitte lesen.info"
"Formular.dok"
"Formular.dok.info"
"Drucke Formular"
"Drucke Formular.info"
"PrintOut")
(optional force askuser)
)
(complete 80)
; Beispielkonto kopieren
(copyfiles
(prompt "Kopiere Beispielkonto")
(help "")
(source "Beispiel")
(dest exampledir)
(optional force askuser)
(all)
)
(copyfiles
(prompt "Kopiere Oberbegriffe")
(help "")
(source "")
(dest @default-dest)
(choices "Oberbegriffe.spec")
(optional force askuser)
)
(complete 90)
(set assign (cat "Assign AmigaKonto: \"" @default-dest "\""))
; Assign in user-startup aufnehmen
(startup "AmigaKonto"
(prompt "Es wird ein Assign in der user-startup benötigt. "
"Bitte \'Proceed\' anklicken, um hiermit fortzufahren.\n")
(help "AmigaKonto wird über das logische Laufwerk \"AmigaKonto:\" "
"angesprochen und benötigt deshalb einen Verweis auf "
"das entsprechende Festplattenverzeichnis. Dieser Verweis "
"wird beim Amiga in der Datei 'user-startup' durch einen "
"Assign-Befehl hergestellt. Diese Installation fügt den "
"benötigten Befehl selbständig ein.\n")
(command assign)
)
(complete 100)
(message "\nInstallation beendet\n\n"
"'AmigaKonto Demo V2.2' befindet sich nun im Verzeichnis:\n'" @default-dest "'\n\n"
"Setzen Sie Ihren Amiga zurück, bevor Sie die Kontoverwaltung starten.")
(exit (quiet))